// библиотека для работы I²C
#include <Wire.h>
// библиотека для работы с модулями IMU
#include <TroykaIMU.h>
// библиотека для работы с устройствами по SPI
#include <SPI.h>
// библиотека для работы с SD-картой
#include <SD.h>
// библиотека для работы с GPS устройством
#include <TroykaGPS.h>

// создаём объект класса GPS и передаём в него объект Serial1 
GPS gps(Serial1);
// создаём объект для работы с акселерометром
Accelerometer accel;

// пин светодиода
#define LED_PIN             A0
// пин кнопки
#define BUTTON_PIN          13
// пин CS micro-sd карты
#define SD_CHIP_SELECT_PIN  9
// интервал времени записи данных на карту
#define INTERVAL            5000
// задаём размер массива для времени, даты, широты и долготы
#define MAX_SIZE_MASS 16
// массив для хранения текущего времени
char time[MAX_SIZE_MASS];
// состояние записи на карту памяти
bool stateRec = false;
// запоминаем текущее время
long startMillis = millis();
// счётчк записи
int counter = 0;

void setup()
{
  // устанавливаем светодиод в режим выхода
  pinMode(LED_PIN, OUTPUT);
  // устанавливаем кнопку в режим входа
  pinMode(BUTTON_PIN, INPUT_PULLUP);
  // открываем последовательный порт для мониторинга действий в программе
  Serial.begin(115200);
  // ждём, пока не откроется монитор последовательного порта
  // для того, чтобы отследить все события в программе
  while (!Serial) {
  }
  Serial.print("Serial init OK\r\n");
  // открываем Serial-соединение с GPS-модулем
  Serial1.begin(115200);
  // выводим информацию об инициализации в Serial-порт
  Serial.println("Initializing SD card...");
  // инициализируем SD-карту
  while (!SD.begin(SD_CHIP_SELECT_PIN)) {
    Serial.println("Card failed, or not present");
    delay(1000);
  }
  // выводим информацию в Serial-порт
  Serial.println("Card initialized");
  // выводим сообщение о начале инициализации акселерометра
  Serial.println("Initializing accelerometer...");
  // инициализация акселерометра
  accel.begin();
  // устанавливаем чувствительность акселерометра
  // 2g — по умолчанию, 4g, 8g
  accel.setRange(RANGE_2G);
  // выводим сообщение об удачной инициализации
  Serial.println("Accelerometer initialized");
}
 
void loop()
{
  // Фиксируем нажатие кнопки
  if (digitalRead(BUTTON_PIN)) {
    // меняем состояние «запись» / «не запись» на карту памяти 
    stateRec = !stateRec;
    // меняем состояние светодиода индикации
    digitalWrite(LED_PIN, stateRec);
  }

  // если пришли данные с gps-модуля
  if (gps.available()) {
    // считываем данные и парсим
    gps.readParsing();
    // считываем состояние GPS-модуля
    switch(gps.getState()) {
      // всё OK
      case GPS_OK:
        Serial.println("GPS is OK");
        // если прошёл заданный интервал времени и запись данных включена
        if (millis() - startMillis > INTERVAL && stateRec) {
          // сохраняем данные GPS и акселерометра на карту памяти
          saveSD();
          // запоминаем текущее время
          startMillis = millis();
        }
        break;
      // ошибка данных
      case GPS_ERROR_DATA:
        Serial.println("GPS error data");
        break;
      // нет соединение со спутниками
      case GPS_ERROR_SAT:
        Serial.println("GPS no connect to satellites");
        break;
    }
  }
}

// функция сохарение данных на карту памяти
void saveSD() {
  File dataFile = SD.open("dataGPS.csv", FILE_WRITE);
  // если файл существует и открылся
  if (dataFile) {
    // считывает текущее время
    gps.getTime(time, MAX_SIZE_MASS);
    // записываем время на карту памяти
    // считываем и записываем координаты широты и долготы на карту памяти
    dataFile.print(gps.getLatitudeBase10(), 6);
    dataFile.print("\t");
    dataFile.print(gps.getLongitudeBase10(), 6);
    dataFile.print("\t");
    dataFile.print(counter++);
    dataFile.print("\t");
    dataFile.print(gps.getSpeedKm());
    dataFile.print("km/h");
    dataFile.print("\t");
    dataFile.print(accel.readAX());
    dataFile.print("\t");
    dataFile.print(accel.readAX());
    dataFile.print("\t");
    dataFile.println(time);
    // записываем данные направления и величины ускорения в м/с² по оси X и Y
    dataFile.close();
    Serial.println("Save OK");
  } else {
    Serial.println("Error opening dataGPS.csv");
  }
}