====== Метеостанция термометром, гигрометром и барометром  ======


**[[arduino-projects:start|Проекты на Arduino Uno и Slot Shield]]**

Метеозависимым людям крайне важно знать не только температуру, но и атмосферное давление. Для этого добавим к метеостанции датчик атмосферного давления — [[amp>product/troyka-barometer?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|электронный барометр]].

{{ :arduino-projects:weather-station:weatherstation_fin3.png |}}

В остальном — это обычная метеостанция на Ардуино. Управляющая плата — оригинальная [[amp>product/arduino-uno?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Arduino Uno]]. За температуру и влажность отвечает  [[amp>product/troyka-meteo-sensor?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|цифровой метеосенсор]].

  * Платформы: [[amp>product/arduino-uno?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Arduino Uno]], [[amp>product/arduino-leonardo?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Arduino Leonardo]], [[amp>product/iskra-neo?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Iskra Neo]]
  * Язык программирования: Arduino (C++)

===== Что потребуется =====

[[amp>collection/weather-station?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki | Полный сет]] компонентов проекта. В сет входят:
  * [[amp>product/arduino-uno?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Arduino Uno]]
  * [[amp>product/arduino-troyka-slot-shield?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Troyka Slot Shield]]
  * цифровой [[amp>product/troyka-meteo-sensor?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|метеодатчик]]
  * четырёхразряный индикатор [[amp>product/troyka-quad-display?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Quad Display]]
  * [[amp>product/troyka-barometer?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|барометр]]
  * [[amp>product/sealed-temperature-sensor-ds18b20?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|датчик температуры DS18B20]] и [[amp>product/troyka-pull-up?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|модуль подтяжки]]

===== Видеоинструкция =====

{{youtube>eUlIHs75VaY?large}}

===== Как собрать =====

Установите [[amp>product/arduino-troyka-slot-shield?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Troyka Slot Shield]] на [[amp>product/arduino-uno?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Arduino Uno]]
{{ :arduino-projects:weather-station:weatherstation0.png |}}

Подключите [[amp>product/troyka-quad-display?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|метеодатчик]] к пинам  I²C разъёма ''A''.
{{ :arduino-projects:weather-station:weatherstation1.png |}}

Вставьте [[amp>product/troyka-quad-display?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Quad Display]] в разъёмы ''E'' и ''F''. Пин ''CS'' подключите к ''10'' пину Arduino.
{{ :arduino-projects:weather-station:weatherstation2.png |}}

[[amp>product/troyka-barometer?utm_source=proj&utm_campaign=arduino-slot-proj-8&utm_medium=wiki|Барометр]] вставьте в  пины ''I²C'' разъёма ''B''.
{{ :arduino-projects:weather-station:weatherstation3.png |}}

===== Скетч =====

Прошейте контроллер скетчем через [[articles:arduino-ide-install|Arduino IDE]].

<code C weather-station-barometr.ino>
// библиотека для работы I²C
#include <Wire.h>
// библиотека для работы с метеосенсором
#include <TroykaMeteoSensor.h>
// Подключаем библиотеку для работы с дисплеем
#include <QuadDisplay2.h>
// библиотека для работы с модулями IMU
#include <TroykaIMU.h>

// создаём объект для работы с метеосенсором
TroykaMeteoSensor meteoSensor;
// создаём объект класса QuadDisplay и передаём номер пина CS
QuadDisplay qd(10);
// создаём объект для работы с барометром
Barometer barometer;

// перечисляем имена операций, которые мы будем выводить на дисплей
enum {
  TEMP_IN,    // имя для операции, которая выводит на дисплей температуру с метеосенсора
  CEL,        // имя для операции, которая выводит на дисплей символ °C
  HUM_IN,     // имя для операции, которая выводит на дисплей влажность с метеосенсора
  PPM,        // имя для операции, которая выводит на дисплей символ %
  BAR_IN,     // имя для операции, которая выводит на дисплей давление с барометра в миллиметрах ртутного столба
  MER,        // имя для операции, которая выводит на дисплей надпись "Hg"
  EMPTY       // имя для операции, которая очищает дисплей
};
// создаем массив, в котором будем хранить последовательность операций
int chain[] = {
  TEMP_IN,
  CEL,
  HUM_IN,
  PPM,
  BAR_IN,
  MER,
  EMPTY
};

// создаем объект класса long для хранения счетчика
unsigned long respite_Time = 0;

// создаем объект для регулировки времени показа значений на экране
int slowdown_qd = 1000;
// создаем объект для хранения номера выполняемой операции
int number_qd = 0;

void setup() {
  // инициализация дисплея
  qd.begin();
  // инициализируем метеосенсора
  meteoSensor.begin();
  // инициализация барометра
  barometer.begin();
}

void loop() {
  // запускаем бесконечный счетчик. Его содержимое будет обрабатываться с периодом равным slowdown_qd
  if (millis() - respite_Time > slowdown_qd) {
    // запускаем процесс, который будет выполнять операции согласно последовательности в chain
    switch (chain[number_qd]) {
      case TEMP_IN:
        showData(meteoSensor.getTemperatureC());
        break;
      case CEL:
        qd.displayDigits(QD_NONE, QD_NONE, QD_DEGREE, QD_C);
        break;
      case HUM_IN:
        showData(meteoSensor.getHumidity());
        break;
      case PPM:
        qd.displayDigits(QD_NONE, QD_NONE, QD_DEGREE, QD_UNDER_DEGREE);
        break;
      case BAR_IN:
        qd.displayInt(barometer.readPressureMillimetersHg());
        break;
      case MER:
        qd.displayDigits(QD_NONE, QD_NONE, QD_H, QD_9);
        break;
      case EMPTY:
        qd.displayClear();
        break;
    }
    number_qd++;
    // проверяем не превысил ли номер операции количество операций
    if (number_qd > sizeof(chain) / sizeof(int) - 1)
      number_qd = 0;
    respite_Time = millis();
  }
}


// функция работы датчика температуры и влажности
void showData(float data) {
  // считываем данные с датчика
  int stateSensor = meteoSensor.read();
  switch (stateSensor) {
    // выводим показания на дисплей
    case SHT_OK:
      qd.displayFloat(data, 1);
      break;
    // выводим сообщение "Errd", если ошибка данных или сенсор не подключён
    case SHT_ERROR_DATA:
      qd.displayDigits(QD_E, QD_r, QD_r, QD_d);
    // выводим сообщение "ErrC", если ошибка контрольной суммы
    case SHT_ERROR_CHECKSUM:
      qd.displayDigits(QD_E, QD_r, QD_r, QD_C);
      break;
  }
}
</code>

====== Часто задаваемые вопросы ======

> Где скачать необходимые библиотеки и как их установить?

  * [[https://github.com/amperka/TroykaMeteoSensor|Библиотека для работы с метеосенсором]]
  * [[https://github.com/amperka/QuadDisplay2|Библиотека для работы с дисплеем]]
  * [[https://github.com/amperka/Troyka-IMU|Библиотека для работы с IMU]]

  * [[программирование:библиотеки|Как установить библиотеку]]

> У моего модуля QuadDisplay всего три ноги и расположены они слева. Можно ли использовать его в этом проекте?

У вас предыдущая версия модуля. Она снята с производства пару лет назад. С этим скетчем, библиотекой и схемой сборки модуль работать не будет.