Эксперимент 9. Миксер

← Мерзкое пианино | Оглавление | Кнопочный переключатель →

В этом эксприменте мы создаем модель миксера с двумя скоростями работы.

• Полевой транзистор
• Мотор

• 1 плата Arduino Uno
• беспаечная макетная плата
• 3 тактовых кнопки
• 1 коллекторный двигатель
• 1 выпрямительный диод
• 1 полевой MOSFET-транзистор
• 15 проводов «папа-папа»
• 1 клеммник, если вы используете мотор с проводами, которые плохо втыкаются в макетку

• еще 1 кнопка
• еще 2 провода

• Защитный диод нам нужен для того, чтобы ток обратного направления, который начнет создавать двигатель, вращаясь по инерции, не вывел из строя транзистор.
• Не перепутайте полярность диода, иначе, открыв транзистор, вы устроите короткое замыкание!
• Причину отсутствия подтягивающих/стягивающих резисторов в схеме вы поймете, ознакомившись с программой.
• Мы подключили питание схемы к выходу Vin платы микроконтроллера, потому что, в отличие выхода 5V, отсюда можно получить напряжение, подключенное к плате, без изменений и без ограничений по величине тока.

p090_mixer.ino

#define MOTOR_PIN        9
#define FIRST_BUTTON_PIN 5
#define BUTTON_COUNT     3
// имена можно давать не только числам, но и целым выражениям.
// Мы определяем с каким шагом (англ. step) нужно менять
// скорость (англ. speed) мотора при нажатии очередной кнопки
#define SPEED_STEP  (255 / (BUTTON_COUNT - 1))
 
void setup()
{
  pinMode(MOTOR_PIN, OUTPUT);
  // на самом деле, в каждом пине уже есть подтягивающий
  // резистор. Для его включения необходимо явно настроить пин
  // как вход с подтяжкой (англ. input with pull up)
  for (int i = 0; i < BUTTON_COUNT; ++i)
    pinMode(i + FIRST_BUTTON_PIN, INPUT_PULLUP);
}
 
void loop()
{
  for (int i = 0; i < BUTTON_COUNT; ++i) {
    // если кнопка отпущена, нам она не интересна. Пропускаем
    // оставшуюся часть цикла for, продолжая (англ. continue)
    // его дальше, для следующего значения i
    if (digitalRead(i + FIRST_BUTTON_PIN))
      continue;
 
    // кнопка нажата — выставляем соответствующую ей скорость
    // мотора. Нулевая кнопка остановит вращение, первая
    // заставит крутиться в полсилы, вторая — на полную
    int speed = i * SPEED_STEP;
 
    // подача ШИМ-сигнала на мотор заставит его крутиться с
    // указанной скоростью: 0 — стоп машина, 127 — полсилы,
    // 255 — полный вперёд!
    analogWrite(MOTOR_PIN, speed);
  }
}

• Мы использовали новый режим работы портов: INPUT_PULLUP. На цифровых портах Arduino есть встроенные подтягивающие резисторы, которые можно включить указанным образом одновременно с настройкой порта на вход. Именно поэтому мы не использовали резисторы при сборке схемы.
• На каждой итерации цикла мы задаем мотору скорость вращения, пропорциональную текущему значению счетчика. Но выполнение инструкций не дойдет до назначения новой скорости, если при проверке нажатия кнопки она окажется отпущенной. Инструкция continue, которая выполнится в этом случае, отменит продолжение данной итерации цикла и выполнение программы продолжится со следующей. А мотор будет крутиться со скоростью, заданной при последнем нажатии на какую-то из кнопок.

1. Зачем в схеме использован диод?
2. Почему мы использовали полевой MOSFET-транзистор, а не биполярный?
3. Почему мы не использовали резистор между портом Arduino и затвором транзистора?
4. Как работает инструкция continue, использованная в цикле for?

1. Внесите единственное изменение в программу, после которого максимальной скоростью вращения мотора составит половину от возможной.
2. Перепишите программу без использования инструкции continue.
3. Добавьте в схему еще одну кнопку, чтобы у миксера стало три режима. Понадобилось ли изменять что-либо в программе?

← Мерзкое пианино | Оглавление | Кнопочный переключатель →