Текстовый экран 20×4 / I²C пригодится для вывода показаний датчиков, отображения простых меню, подсказок и приветствий.

В качестве примера подключим дисплей к управляющей плате Arduino Uno.

Для коммуникации понадобится Breadboard Half и соединительные провода «папа-папа».

Для упрощения работы с LCD-дисплеем используйте встроенную библиотеку Библиотека для Arduino «Liquid Crystal I²C». В ней вы найдёте примеры кода с подробными комментариями.

Для вывода первой программы приветствия, воспользуйтесь кодом вроде этого:

hello-amperka.ino

// подключаем библиотеку LiquidCrystal_I2C
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
 
// создаем объект-экран, передаём используемый адрес 
// и разрешение экрана:
LiquidCrystal_I2C lcd(0x38, 20, 4);
 
void setup() {
  // инициализируем экран
  lcd.init();
  // включаем подсветку
  lcd.backlight();
  // устанавливаем курсор в колонку 0, строку 0
  lcd.setCursor(0, 0);
  // печатаем первую строку
  lcd.print("Hello Amperka");
  // устанавливаем курсор в колонку 0, строку 1
  // на самом деле это вторая строка, т.к. нумерация начинается с нуля
  lcd.setCursor(0, 1);
  // печатаем вторую строку
  lcd.print("Do It Yourself");
  // устанавливаем курсор в колонку 0, строку 2 
  lcd.setCursor(0, 2);
  // печатаем третью строку
  lcd.print("LCD Screen 20x4");
  // устанавливаем курсор в колонку 0, строку 3
  lcd.setCursor(0, 3);
  // печатаем четвёртую строку
  lcd.print("www.Amperka.ru");
}
 
void loop() {
}

Существует способ вывода кириллицы на текстовые дисплеи с помощью таблицы знакогенератора.

Дисплейный модуль хранит в памяти две страницы знакогенератора, которые состоят из различных символов и букв.

Для вывода символа на дисплей необходимо передать его номер в шестнадцатеричной системе из таблицы знакогенератора.

Так букве Я соответствует код B1 в шестнадцатеричной системе. Чтобы передать на экран строку «Яndex», необходимо в явном виде с помощью последовательности \x## встроить в строку код символа:

lcd.print("\xB1ndex");

Сравните две строки кода для вывода надписи «Яeee»:

lcd.print("\xB1eee"); // ошибка
lcd.print("\xB1""eee"); // правильно

Используя полученную информацию выведем на дисплей сообщение «Привет от Амперки!»:

hello-amperka-rus.ino

// подключаем библиотеку LiquidCrystal_I2C
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
 
// создаем объект-экран
// передаём используемый адрес и разрешение экрана
LiquidCrystal_I2C lcd(0x38, 20, 4);
 
void setup() {
  // инициализируем экран
  lcd.init();
  // включаем подсветку
  lcd.backlight();
  // устанавливаем курсор в колонку 7, строку 0
  // на самом деле это первая строка, т.к. нумерация начинается с нуля
  lcd.setCursor(7, 0);
  // печатаем первую строку
  lcd.print("\xA8""p""\xB8\xB3""e\xBF");
  // устанавливаем курсор в колонку 9, строку 1
  // на самом деле это вторая строка, т.к. нумерация начинается с нуля
  lcd.setCursor(9, 1);
  // печатаем вторую строку
  lcd.print("o\xBF");
  // устанавливаем курсор в колонку 7, строку 2
  // на самом деле это третья строка, т.к. нумерация начинается с нуля
  lcd.setCursor(7, 2);
  // печатаем третью строку
  lcd.print("A\xBC\xBE""ep\xBA\xB8");
}
 
void loop() {
}

Дисплейный модуль хранит в памяти две страницы знакогенератора. По умолчанию установлена нулевая страница. Для переключения между страницами используйте методы:

// переключение с нулевой страницы на первую
command(0b101010);
// переключение с первой страницы на нулевую
command(0b101000);

Рассмотрим пример, в котором одна и та же строка будет отображаться по-разному — в зависимости от выбранной страницы.

change-page.ino

// подключаем библиотеку LiquidCrystal_I2C
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
 
// создаем объект-экран, передаём используемый адрес 
// и разрешение экрана:
LiquidCrystal_I2C lcd(0x38, 20, 4);
 
void setup() {
  // инициализируем экран
  lcd.init();
  // включаем подсветку
  lcd.backlight();
  // устанавливаем курсор в колонку 7, строку 0
  // на самом деле это первая строка, т.к. нумерация начинается с нуля
  lcd.setCursor(7, 0);
  // печатаем  строку
  lcd.print("\x9b\x9c\x9d\x9e\x9f");
}
 
void loop() {
  // устанавливаем 0 станицу знакогенератора (стоит по умолчанию) 
  lcd.command(0b101000);
  // ждём 1 секунду
  delay(1000);
  // устанавливаем 1 станицу знакогенератора
  lcd.command(0b101010);
  // ждём 1 секунду
  delay(1000);
}

Используя шину I²C можно подключить несколько дисплеев одновременно, при этом количество занятых пинов останется прежним. Подробнее читайте в нашей документации.

После физического смены адреса экрана, подключите дополнительный дисплей параллельно к пинам I²C, а в коде программы инициализируйте работу с двумя дисплеями.

two-displays.ino

// подключаем библиотеку LiquidCrystal_I2C
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
 
// создаем объекты-экранов, передаём используемые адреса 
// и разрешение экранов:
LiquidCrystal_I2C lcd1(0x38, 20, 4);
LiquidCrystal_I2C lcd2(0x39, 20, 4);
 
void setup() {
  // инициализируем первый экран
  lcd1.init();
  // включаем подсветку
  lcd1.backlight();
  // выводим информацию на первый дисплей
  // устанавливаем курсор
  lcd1.setCursor(6, 1);
  // печатаем первую строку
  lcd1.print("Display_1");
  lcd1.setCursor(4, 2);
  lcd1.print("Address: 0x38");
  // инициализируем второй экран
  lcd2.init();
  // включаем подсветку
  lcd2.backlight();
  // выводим информацию на второй дисплей
  // устанавливаем курсор
  lcd2.setCursor(6, 1);
  // печатаем первую строку
  lcd2.print("Display_2");
  lcd2.setCursor(4, 2);
  lcd2.print("Address: 0x39");
}
 
void loop() {
}

В качестве примера подключим дисплей к управляющей плате Iskra JS.

Для коммуникации понадобится Breadboard Half и соединительные провода «папа-папа».

Для работы с LCD-дисплеем из среды Espruino существует библиотека HD44780.

Для вывода программы приветствия, воспользуйтесь скриптом:

hello-amperka.js

// HD44780 — контроллер монохромных жидкокристаллических знакосинтезирующих дисплеев
 
// настраиваем интерфейс I2C
PrimaryI2C.setup({sda: SDA, scl: SCL});
// подключаем библиотеку и указываем адрес дисплея
var lcd = require("HD44780").connectI2C(PrimaryI2C, 0x38);
 
// включаем подсветку
PrimaryI2C.writeTo(0x38, 0x08);
// выключить подсветку
// PrimaryI2C.writeTo(0x38, 0x00);
 
// печатаем первую строку
lcd.print("Hello Amperka");
// устанавливаем курсор в колонку 0, строку 1
// на самом деле это вторая строка, т.к. нумерация начинается с нуля
lcd.setCursor(0, 1);
// печатаем вторую строку
lcd.print("Do It Yourself");
// устанавливаем курсор в колонку 0, строку 2 
lcd.setCursor(0, 2);
// печатаем третью строку
lcd.print("LCD Screen 20x4");
// устанавливаем курсор в колонку 0, строку 3
lcd.setCursor(0, 3);
// печатаем четвёртую строку
lcd.print("www.Amperka.ru");

Вывод кириллицы на дисплей с помощью платформы Iskra JS доступен через встроенную в дисплей таблицу знакогенератора.

Дисплейный модуль хранит в памяти две страницы знакогенератора, которые состоят из различных символов и букв.

Для вывода символа на дисплей необходимо передать его номер в шестнадцатеричной системе из таблицы знакогенератора.

Так букве Я соответствует код B1 в шестнадцатеричной системе. Чтобы передать на экран строку «Яndex», необходимо в явном виде с помощью последовательности \x## встроить в строку код символа:

lcd.print("\xB1ndex");

Сравните две строки кода для вывода надписи «Яeee»:

lcd.print("\xB1eee"); // ошибка
lcd.print("\xB1"+"eee"); // правильно

Используя полученную информацию выведем на дисплей сообщение «Привет, Амперка!»:

hello-amperka-rus.js

// HD44780 — контроллер монохромных жидкокристаллических знакосинтезирующих дисплеев
 
// настраиваем интерфейс I2C
PrimaryI2C.setup({sda: SDA, scl: SCL});
// подключаем библиотеку и указываем адрес дисплея
var lcd = require("HD44780").connectI2C(PrimaryI2C, 0x38);
 
// включаем подсветку
PrimaryI2C.writeTo(0x38, 0x08);
// выключить подсветку
// PrimaryI2C.writeTo(0x38, 0x00);
 
// устанавливаем курсор в колонку 7, строку 0
// на самом деле это первая строка, т.к. нумерация начинается с нуля
lcd.setCursor(7, 0);
// печатаем первую строку
lcd.print("\xA8"+"p"+"\xB8\xB3"+"e\xBF");
// устанавливаем курсор в колонку 9, строку 1
// на самом деле это вторая строка, т.к. нумерация начинается с нуля
lcd.setCursor(9, 1);
// печатаем вторую строку
lcd.print("o\xBF");
// устанавливаем курсор в колонку 7, строку 2
// на самом деле это третья строка, т.к. нумерация начинается с нуля
lcd.setCursor(7, 2);
// печатаем третью строку
lcd.print("A\xBC\xBE"+"ep\xBA\xB8");

Дисплейный модуль хранит в памяти две страницы знакогенератора. По умолчанию установлена нулевая страница. Для переключения между страницами используйте методы:

// переключение с нулевой страницы на первую
command(0b101010);
// переключение с первой страницы на нулевую
command(0b101000);

Рассмотрим пример, в котором одна и та же строка будет отображаться по-разному — в зависимости от выбранной страницы.

change-page.js

// HD44780 — контроллер монохромных жидкокристаллических знакосинтезирующих дисплеев
 
// настраиваем интерфейс I2C
PrimaryI2C.setup({sda: SDA, scl: SCL});
// подключаем библиотеку и указываем адрес дисплея
var lcd = require("HD44780").connectI2C(PrimaryI2C, 0x38);
 
// включаем подсветку
PrimaryI2C.writeTo(0x38, 0x08);
// выключить подсветку
// PrimaryI2C.writeTo(0x38, 0x00);
 
// создаём переменную состояния
var state = false;
// устанавливаем курсор в колонку 7, строку 0
// на самом деле это первая строка, т.к. нумерация начинается с нуля
lcd.setCursor(7, 0);
// печатаем строку
lcd.print("\x9b\x9c\x9d\x9e\x9f");
 
setInterval(function() {
  // каждую секунду меняем переменую состояния
  state = !state;
  // вызываем функцию смены адреса страницы
  lcdChangePage();
}, 1000);
 
function lcdChangePage () {
  if (state) {
    // устанавливаем 0 станицу знакогенератора (стоит по умолчанию) 
    lcd.write(0b101000, 1);
  } else {
    // устанавливаем 1 станицу знакогенератора
    lcd.write(0b101010, 1);
  }
}

Для пользователей Espruino есть возможность выводить супер большие числа «Big Number Module» на текстовой дисплей 20×4.

Размер цифры в данном шрифте: 3 символа по столбцам и 4 по строкам.

big-number.js

// HD44780 — контроллер монохромных жидкокристаллических знакосинтезирующих дисплеев
 
// настраиваем интерфейс I2C
PrimaryI2C.setup({sda: SDA, scl: SCL});
// подключаем библиотеку и указываем адрес дисплея
var lcd = require("HD44780").connectI2C(PrimaryI2C, 0x38);
 
// включаем подсветку
PrimaryI2C.writeTo(0x38, 0x08);
// выключить подсветку
// PrimaryI2C.writeTo(0x38, 0x00);
 
// создаём переменную для работы с большим шрифтом цифр
var disp = require("big_number").use(lcd);
// выводим число «31337»
disp.showDigit(1,3);
disp.showDigit(4,1);
disp.showDigit(8,3);
disp.showDigit(12,3);
disp.showDigit(16,7);

Используя шину I²C можно подключить несколько дисплеев одновременно, при этом количество занятых пинов останется прежним. Подробнее читайте в нашей документации.

После физического смены адреса экрана, подключите дополнительный дисплей параллельно к пинам I²C, а в коде программы инициализируйте работу с двумя дисплеями.

two-displays.js

// HD44780 — контроллер монохромных жидкокристаллических знакосинтезирующих дисплеев
 
// настраиваем интерфейс I2C
PrimaryI2C.setup({sda: SDA, scl: SCL});
// создаем объекты дисплеев, подключаем библиотеку и указываем адреса
var lcd1 = require("HD44780").connectI2C(PrimaryI2C, 0x38);
var lcd2 = require("HD44780").connectI2C(PrimaryI2C, 0x39);
 
// включаем подсветку первого дисплея
PrimaryI2C.writeTo(0x38, 0x08);
// выключить подсветку
// PrimaryI2C.writeTo(0x38, 0x00);
 
// включаем подсветку второго дисплея
PrimaryI2C.writeTo(0x39, 0x08);
// выключить подсветку
// PrimaryI2C.writeTo(0x39, 0x00);
 
// выводим информацию на первый дисплей
// устанавливаем курсор
lcd1.setCursor(6, 1);
// печатаем первую строку
lcd1.print("Display_1");
lcd1.setCursor(4, 2);
lcd1.print("Address: 0x38");
// выводим информацию на второй дисплей
// устанавливаем курсор
lcd2.setCursor(6, 1);
// печатаем первую строку
lcd2.print("Display_2");
lcd2.setCursor(4, 2);
lcd2.print("Address: 0x39");

Дисплей удобен для отображения показаний модулей и сенсоров. Сделаем задатки «Умного Дома», а именно «комнатный термометр».

1. Управляющая платформа Arduino Uno или Iskra JS
2. Текстовый экран 20×4
3. Troyka Shield
4. Аналоговый термометр (Troyka-модуль)
5. Соединительные провода «папа-папа»

1. Возьмите Troyka Shield и установите сверху на управляющую плату — Arduino или Iskra JS.
2. Подключите текстовый экран к управляющей платформе, используя схему подключения дисплея
3. Подключите аналоговый термометр к управляющей плате через 3-проводной шлейф к аналоговому пину A0. В итоге должна получится схема.
4. Прошейте управляющую платформу кодом, приведённым ниже.

Для работы с термометром удобно использовать библиотеку TroykaThermometer.

thermometer-room.ino

// подключаем библиотеку LiquidCrystal_I2C
#include <Wire.h> 
#include <LiquidCrystal_I2C.h>
 
// создаем объект-экран, передаём используемый адрес 
// и разрешение экрана:
LiquidCrystal_I2C lcd(0x38, 20, 4);
 
// подключим библиотеку для работы с термометром
#include <TroykaThermometer.h>
 
// создаём объект для работы с аналоговым термометром
// и передаём ему номер пина выходного сигнала
TroykaThermometer thermometer(A0);
 
void setup() {
  // инициализируем экран
  lcd.init();
  // включаем подсветку
  lcd.backlight();
}
 
void loop() {
  // очищаем дисплей
  lcd.clear();
 
  // считываем данные с аналогового термометра
  thermometer.readData();
 
  // считываем показания с датчика температуры
  float temperature = thermometer.getTemperatureC();
 
  // устанавливаем курсор
  // выводим результат на дисплей
  lcd.setCursor(4, 1);
  lcd.print("Temperature");
  lcd.setCursor(8, 2);
  lcd.print(temperature);
  lcd.print("\x99""C");
  delay(500);
}

thermometer-room.js

// HD44780 — контроллер монохромных жидкокристаллических знакосинтезирующих дисплеев
 
// настраиваем интерфейс I2C
PrimaryI2C.setup({sda: SDA, scl: SCL});
// подключаем библиотеку
var lcd = require("HD44780").connectI2C(PrimaryI2C, 0x38);
 
// включаем подсветку
PrimaryI2C.writeTo(0x38, 0x08);
// выключить подсветку
// PrimaryI2C.writeTo(0x38, 0x00);
 
// создаём переменную для работы с датчиком температуры
var thermometer = require('@amperka/thermometer')
 .connect(A0);
 
// устанавливаем курсор в колонку 4, строку 1
// на самом деле это вторая строка, т.к. нумерация начинается с нуля
lcd.setCursor(4, 1);
// выводим на дисплей строку «Temperature»
lcd.print("Temperature");
 
// каждую секунду считываем данные с датчика температуры и выводим на дисплей
setInterval(function() {
  var celsius = thermometer.read('C');
  lcd.setCursor(8, 2);
  lcd.print(celsius.toFixed(0) + "\x99"+"C");
}, 1000);

Дисплей MT-20S4A-I умеет отображать все строчные и прописные буквы латиницы и кириллицы, а также типографские символы. Для любителей экзотики есть возможность создавать собственные иконки.

Экран выполнен на жидкокристаллической матрице, которая отображает 4 строки по 20 символов. Каждый символ состоит из отдельного знакоместа 5×8 пикселей.

Матрица индикатора подключена к встроенному чипу КБ1013ВГ6 с драйвером расширителя портов, которые выполняют роль посредника между экраном и микроконтроллером.

Для экономии пинов микроконтроллера на плате дисплея также распаян дополнительный преобразователь интерфейсов INF8574A: микросхема позволит общаться экрану и управляющей плате по двум проводам через интерфейс I²C.

На плате дисплея выведено 18 контактов для подведения питания и взаимодействия с управляющей электроникой.

Экран совместим со всеми контроллерами с логическим напряжением от 3,3 до 5 вольт. Но для питания самого индикатора (пин VCC) необходимо строго 5 вольт. Если в вашем проекте нет линии 5 вольт, обратите внимание на дисплей текстовый экран 20×4 / I²C / 3,3 В.

Дисплей может работать в трёх режимах:

• 8-битный режим — в нём используются и младшие и старшие биты (DB0-DB7)
• 4-битный режим — в нём используются только младшие биты (DB4-DB7)
• I²C режим — данные передаются по протоколу I²C/TWI. Адрес дисплея 0x38.

Использовать восьмибитный и четырёхбитный режим в данном дисплее не целесообразно. Ведь главное достоинство этой модели именно возможность подключения через I²C. Если всё-таки есть необходимость использовать 4-битный или 8-битный режим, читайте документацию на текстовый экран 20×4.

Для подключения питания к дисплею необходимо пять контактов:

Но если запаять перемычки J3 и J4 на обратной стороне дисплея, количество контактов питания можно сократить до трёх, объединив цепь питания и подсветки дисплея.

Используя шину I²C можно подключить несколько дисплеев одновременно, при этом количество занятых пинов останется прежним.

Для общения с каждым дисплеем отдельно, необходимо установить в них разные адреса. Для смены адреса на обратной стороне дисплея установлены контактные площадки J0, J1 и J2.

Капнув припоем на контактные площадки, мы получим один из семи дополнительных адресов:

• L нет припоя, соответственно нет электрического контакта.
• H есть припой, соответственно есть электрический контакт.

• Тип дисплея: текстовый
• Цвет: монохромный
• Технология: LCD (Liquid Crystal Display)
• Индикация: 4 строки по 20 символов
• Драйвера матрицы: КБ1013ВГ6
• Расширитель I²C: INF8574A
• Интерфейс: I²C, параллельный 4/8 бит
• Тип подсветки: LED
• Цвет подсветки: зелёный
• Цвет символов: чёрный
• Напряжение питания: 5 В
• Максимальный ток потребления: 1,4 мА
• Потребляемый ток подсветки: 120 мА
• Напряжение логических уровней: 3,3–5 В
• Габариты: 98×60×13 мм

• Текстовый экран 20×4 / I²C в магазине
• Datasheet на текстовый экран MT-20S4A-I
• Datasheet на контроллер КБ1013ВГ6
• Datasheet на I²C расширитель INF8574
• Векторное изображение дисплея
• Библиотека для Arduino «Liquid Crystal I²C»
• Библиотека для Espruino «HD44780»