Хотите подключить мотор к Arduino или Iskra JS?! К сожалению микроконтроллер установленный на управляющих платформах не сможет без посторонней помощи управлять большой нагрузкой. Motor Shield поможет микроконтроллеру управлять коллекторными моторами и шаговыми двигателями.

Motor Shield — это плата расширения, предназначенная для двухканального управления скоростью и направлением вращения коллекторных двигателей постоянного тока, напряжением 5–24 В и максимальным током до двух ампер на канал.

Плата расширения также сможет управлять одним биполярным шаговым двигателем.

1. Установите Motor Shield сверху на управляющую платформу, например Arduino Uno или Iskra JS.
2. Убедитесь в наличии и правильности соединения джамперов на плате Motor Shield:
   • H1 с 4 пином;
   • E1 с 5 пином.
   • E2 с 6 пином;
   • H2 с 7 пином.
3. Подключите внешнее питание для моторов через клеммник ''PWR''.

Подключите два коллекторных мотора к клеммникам M1 и M2 соответственно.

Для начала покрутим каждый мотор в одну, а затем другую сторону.

dc_motors.ino

// подключите один мотор к клемме: M1+ и M1-
// а второй к клемме: M2+ и M2-
// Motor shield использует четыре контакта 4, 5, 6, 7 для управления моторами 
// 4 и 7 — для направления, 5 и 6 — для скорости
#define SPEED_1      5 
#define DIR_1        4
 
#define SPEED_2      6
#define DIR_2        7
 
void setup() {
  // настраиваем выводы платы 4, 5, 6, 7 на вывод сигналов 
  for (int i = 4; i < 8; i++) {     
    pinMode(i, OUTPUT);
  }
} 
 
void loop() {
  // устанавливаем направление мотора «M1» в одну сторону
  digitalWrite(DIR_1, LOW);
  // включаем мотор на максимальной скорости
  analogWrite(SPEED_1, 255);
  // ждём одну секунду
  delay(1000);
 
  // устанавливаем направление мотора «M1» в другую сторону
  digitalWrite(DIR_1, HIGH);
  // ждём одну секунду
  delay(1000);
  // выключаем первый мотор
  analogWrite(SPEED_1, 0);
 
  // устанавливаем направление мотора «M2» в одну сторону
  digitalWrite(DIR_2, LOW);
  // включаем второй мотор на максимальной скорости
  analogWrite(SPEED_2, 255);
  // ждём одну секунду
  delay(1000);
 
  // устанавливаем направление мотора «M2» в другую сторону
  digitalWrite(DIR_2, HIGH);
  // ждём одну секунду
  delay(1000);
 
  // выключаем второй мотор
  analogWrite(SPEED_2, 0);
  // ждём одну секунду
  delay(1000);
}

Усложним задачу. Будем плавно увеличивать скорость первого мотора до максимальной скорости, а потом понижать до полного выключения. Аналогично проделываем со вторым мотором.

dc_motors_pwm.ino

// подключите один мотор к клемме: M1+ и M1-
// а второй к клемме: M2+ и M2-
// Motor shield использует четыре контакта 4, 5, 6, 7 для управления моторами 
// 4 и 7 — для направления, 5 и 6 — для скорости
#define SPEED_1      5 
#define DIR_1        4
 
#define SPEED_2      6
#define DIR_2        7
 
void setup() {
  // настраиваем выводы платы 4, 5, 6, 7 на вывод сигналов 
  for (int i = 4; i < 8; i++) {     
    pinMode(i, OUTPUT);
  }
} 
 
void loop() {
  // устанавливаем направление мотора «M1» в одну сторону
  digitalWrite(DIR_1, LOW);
  // медленно разгоняем мотор
  for (int i = 0; i <= 255; i++) {
    analogWrite(SPEED_1, i);
    Serial.println(i);
    delay(20);
  }
 
  // устанавливаем направление мотора «M1» в другую сторону
  digitalWrite(DIR_1, HIGH);
  // медленно тормозим мотор
  for (int i = 255; i >= 0; i--) {
    analogWrite(SPEED_1, i);
    Serial.println(i);
    delay(20);
  }
 
  // устанавливаем направление мотора «M2» в одну сторону
  digitalWrite(DIR_2, LOW);
  // медленно разгоняем мотор
  for (int i = 0; i <= 255; i++) {
    analogWrite(SPEED_2, i);
    delay(20);
  }
 
  // устанавливаем направление мотора «M2» в другую сторону
  digitalWrite(DIR_2, HIGH);
  // медленно тормозим мотор
  for (int i = 255; i > 0; i--) {
    analogWrite(SPEED_2, i);
    delay(20);
  }
}

Драйвер моторов может на себя также взять управления шаговым двигателем. В качестве примера подключим шаговый двигатель 42STH47-0406A.

Motor Shield поддерживает три режима управления биполярным шаговым двигателем:

• Однофазный полношаговый «wave drive mode»
• Двухфазный полношаговый «full step mode»
• Полушаговый «half step mode»

Протестируем по очереди три режима управления.

step-motor-switch-mode.ino

// пины для управления Motor Shield
#define E1          5
#define E2          6
#define H1          4
#define H2          7
 
// три режима управления шаговым мотором
// однофазный режим
#define WAVE_DRIVE  0
// двухфазный режим
#define FULL_STEP   1
// полушаговый режим
#define HALF_STEP   2
 
// задержка между переключением обмоток
// определяет скорость вращения
int delayTime = 10;
 
unsigned long startTime;
 
// функция выставляет значение на пинах
void doStep(bool E1State, bool H1State, bool E2State, bool H2State) {
  digitalWrite(E1, E1State);
  digitalWrite(H1, H1State);
  digitalWrite(E2, E2State);
  digitalWrite(H2, H2State);
  delay(delayTime);
}
 
// определяем комбинации управляющих импульсов в зависимости от режима
void rotate(byte rotateMode) {
  switch (rotateMode) {
    case WAVE_DRIVE:
      doStep(1, 1, 0, 0);
      doStep(0, 0, 1, 1);
      doStep(1, 0, 0, 0);
      doStep(0, 0, 1, 0);
      break;
 
    case FULL_STEP:
      doStep(1, 1, 1, 1);
      doStep(1, 0, 1, 1);
      doStep(1, 0, 1, 0);
      doStep(1, 1, 1, 0);
      break;
 
    case HALF_STEP:
      doStep(1, 1, 0, 0);
      doStep(1, 1, 1, 1);
      doStep(0, 0, 1, 1);
      doStep(1, 0, 1, 1);
 
      doStep(1, 0, 0, 0);
      doStep(1, 0, 1, 0);
      doStep(0, 0, 1, 0);
      doStep(1, 1, 1, 0);
      break;
  }
}
 
void setup() {
  // настраиваем ножки на выход
  for (int i = 4; i < 8; i++) {
    pinMode(i, OUTPUT);
  }
  // запоминаем текущее время
  startTime = millis();
}
 
void loop() {
  // узнаём время прошедшее с начала работы в миллисекундах
  // и переводим его в секунды
  unsigned long loopTime = (millis() - startTime) / 1000;
  // меняем режим каждую секунду
  rotate(loopTime % 3);
}

Скорость вращения шагового двигателя очень сильно влияет на развиваемый мотором момент. Убедитесь сами. Запустите этот же пример с разными значениями delayTime.

Обратите внимание, что двигатель в однофазном полношаговом режиме позволяет развить гораздо меньший момент, чем в двухфазном полношаговом режиме.

Для лёгкого и быстрого управления шаговым двигателем мы написали библиотеку AmperkaStepper. Она скрывает в себе все тонкости работы с мотором и предоставляет удобные методы.

step-motor-test.ino

// библиотека для работы с шаговым двигателем
#include <AmperkaStepper.h>
 
// создаём объект для работы с шаговым двигателем
// передаём фикированое количество шагов за полный оборот
// смотреть в характеристиках двигателя
AmperkaStepper motor(200);
 
// при использовании Motor Shield на нестандартных пинах
// необходимо педедавать управляющие пины
// Например, для пинов 8, 9, 10, 11
// AmperkaStepper motor(200, 8, 9, 10, 11);
 
void setup() {
  // устанавливаем скорость вращения 30 оборотов в минуту.
  motor.setSpeed(30);
}
 
void loop() {
  // 180° по часовой стрелке в двуфазном режиме
  motor.step(100, FULL_STEP);
  delay(1000);
 
  // 180° против часовой стрелки в однофазном режиме
  motor.step(-100, WAVE_DRIVE);
  delay(1000);
 
  // 180° по часовой стрелке в полушаговом режиме
  motor.step(200, HALF_STEP);
  delay(1000);
 
  // 180° против часовой стрелки в двуфазном режиме
  // этот режим используется по умолчанию, если не передан
  // второй аргумент
  motor.step(-100);
  delay(1000);
}

Подключите два коллекторных мотора к клеммникам M1 и M2 соответственно.

Для начала покрутим каждый мотор в одну, а затем другую сторону.

dc_motors.js

// подключаем библиотеку «motor»
var Motor = require('@amperka/motor');
// подключаем первый мотор канала M1 на Motor Shield
var motorOne = Motor.connect(Motor.MotorShield.M1);
// подключаем второй мотор канала M2 на Motor Shield
var motorTwo = Motor.connect(Motor.MotorShield.M2);
 
// Альтернативный способ подключения с указанием пинов
// var myMotor = Motor.connect({phasePin: P4, pwmPin: P5, freq: 100});
 
// интеварал времени
var time = 1000;
// счётчик
var state = 0;
 
// каждую секунду меняем режим работы
setInterval(() => {
  // останавливаем моторы
  motorOne.write(0);
  motorTwo.write(0);
  state++;
  if (state === 1) {
    motorOne.write(1);
  } else if (state === 2) {
    motorOne.write(-1);
  } else if (state === 3) {
    motorTwo.write(1);
  } else if (state === 4) {
    motorTwo.write(-1);
  } else {
    state = 0;
  }
}, time);

Усложним задачу. Будем плавно увеличивать скорость первого мотора до максимальной скорости, а потом понижать до полного выключения. Аналогично проделываем со вторым мотором.

dc_motors_pwm.js

// подключаем библиотеку «motor»
var Motor = require('@amperka/motor');
// подключаем первый мотор канала M1 на Motor Shield
var motorOne = Motor.connect(Motor.MotorShield.M1);
// подключаем второй мотор канала M2 на Motor Shield
var motorTwo = Motor.connect(Motor.MotorShield.M2);
 
// создаём объект анимация
// для плавного изменения параметров вращения мотора
var animMotor = require('@amperka/animation').create({
  // начальное значение
  // при «0» мотор стоит
  from: 0,
  // конечное значение
  // при «1» мотор вращается с максимальной скоростью в одну сторону
  to: 1,
  // продолжительность полного перехода
  // за 5 секунд мотор пройдёт диапазон значений от нуля до единицы
  duration: 5,
  // шаг обновления: каждые 20 мс
  updateInterval: 0.02
}).queue({
  // после завершения перехода, выполняем ещё одну операцию
  // начальное значение
  // при «-1» мотор вращается с максимальной скоростью в обратную сторону
  from: -1,
  // конечное значение
  // при «0» мотор стоит
  to: 0,
  // продолжительность полного перехода
  // за 5 секунд мотор пройдёт диапазон значений от минус единицы до нуля
  duration: 5
});
 
// номер мотора
var motorNum = motorOne;
// время вращения работы мотора
var time = 10000;
 
// обработчик анимации
animMotor.on('update', function(val) {
  motorNum.write(val);
});
 
// функция работы первого мотора
var startMotorOne = () => {
  motorNum = motorOne;
  animMotor.play();
  setTimeout(() => {
    startMotorTwo();
  }, time);
};
 
// функция работы второго мотора
var startMotorTwo = () => {
  motorNum = motorTwo;
  animMotor.play();
  setTimeout(() => {
    startMotorOne();
  }, time);
};
 
// запускаем функцию работы первого мотора
startMotorOne();

Сердце и мускулы платы — микросхема двухканального H-моста L298P.

Термин «H-мост» появился благодаря графическому изображению схемы, напоминающему букву «Н». H-мост состоит из четырёх ключей. В зависимости от текущего состояние переключателей возможно разное состояние мотора.

Ключи меняем на транзисторы для регулировки скорости мотора с помощью ШИМ-сигнала.

H-мост с силовыми ключами — основная начинка микросхемы L298P для управления скоростью и направлением двигателей.

На плате расширения Motor Shield два контура питания.

• Силовой контур — напряжение для питания моторов от силовой части микросхемы H-моста L298P. При отсутствии питания на силовом контуре, светодиод PWR не горит.
• Цифровой контур — для питания вспомогательной цифровой логики управления микросхемой L298P и светодиодов индикации. Цифровое питание поступает на плату расширения от пина 5V управляющей платы. Если по какой-то причине напряжения на этом пине не оказалось, светодиоды индикации гореть не будут.

Силовое питание подключается через клеммник PWR. Диапазон входного напряжения:

• 5–24 В при снятом джампере PWR JOIN
• 5–12 В при установленном джампере PWR JOIN

Motor Shield использует два контура питания: силовое и цифровое. По умолчанию для питания всей конструкции необходимо два источника напряжения:

• Питания для силовой части через клеммник PWR
• Питания для цифровой части с пина 5V управляющей платформы.

При установки джампера в положение PWR JOIN, происходит объединение контакта Vin управляющей платформы и положительного контакта клеммника PWR. Режим объединённого питания позволяет запитывать управляющую платформу и силовую часть драйвера от одного источника питания.

При объединённом режиме напряжение может быть подано двумя способами:

• на клеммник PWR драйвера моторов
• на внешний разъём питания управляющей платы

При работе двигателей по цепи питания может проходить очень большой ток, на который цепь Vin управляющей платформы не рассчитана. Поэтому выбор для питания клеммника PWR предпочтительнее.

Нагрузка разделена на два независимых канала. К каждому каналу можно подключить один коллекторный мотор. Первый канал на плате обозначен шёлком M1, второй канал — M2.

Обозначения «+» и «−» показывают воображаемые начало и конец обмотки. Если подключить два коллекторных двигателя, чтобы их одноимённые контакты щёточного узла соответствовали одному и тому же обозначению на плате, то при подаче на Motor Shield одинаковых управляющих импульсов, моторы будут вращаться в одну и ту же сторону.

Для запуска двигателя на первом или втором канале установите высокий уровень на пинах скорости E1 или E2 соответственно. Для остановки моторов установите на соответствующих пинах низкий уровень.

Управление скоростью происходит при помощи ШИМ, за счёт быстрого включения и выключения нагрузки.

Пины направления H1 или H2 отвечают за направление вращения двигателей. Смена направления вращения коллекторных двигателей достигается за счёт изменения полярности приложенного к ним напряжения.

• Если выставить на пин направления высокий уровень, то полярность напряжения на клеммниках нагрузки будет соответствовать обозначению «+» и «-» на плате.
• При подаче на пин низкого уровня, напряжение на клеммнике изменится на противоположное.

По умолчанию Motor Shield для управления скоростью и направлением вращения моторов использует пины управляющей платы:

Если в вашем устройстве эти пины уже заняты, например используются для управления Relay Shield), вы можете использовать другой свободный пин.

Для переброски пинов снимите джампер напротив занятого пина и припаяйте проводок между луженым отверстием рядом со снятым джампером и луженым отверстием напротив нужного пина. На этой картинке мы перекинули:

• управляющие пины первого канала H1 и E1: с 4 и 5 пина — на 2 и 3 пин соответственно;
• управляющие пины второго канала H2 и E2: с 7 и 6 — на 8 и 9 пин соответственно.

• Драйвер моторов: L298P
• Количество подключаемых моторов: 2
• Напряжение логической части: 3,3—5 В
• Напряжение силовой части:
  • 5—12 c PWR JOIN
  • 5—24 без PWR JOIN
• Продолжительный ток нагрузки на канал: до 2 A
• Пиковый ток нагрузки на канал: до 3 А в течении 100 мкс

• Motor Shield в магазине.
• Векторное изображение драйвера моторов
• Datasheet на микросхему L298P
• Библиотека для работы с шаговым двигателем при помощи Motor Shield
• Библиотека для Espruino по работе с коллекторными моторами